;; Copyright (C) 2010, 2014-2015 Free Software Foundation, Inc

;; Author: Rocky Bernstein <rocky@gnu.org>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

(eval-when-compile (require 'cl))

(require 'load-relative)
(require-relative-list '("../../common/track" "../../common/core") "realgud-")
(require-relative-list '("init") "realgud:kshdb-")

(declare-function realgud:expand-file-name-if-exists 'realgud-core)
(declare-function realgud-parse-command-arg  'realgud-core)
(declare-function realgud-query-cmdline      'realgud-core)
(declare-function realgud-suggest-invocation 'realgud-core)

;; FIXME: I think the following could be generalized and moved to
;; realgud-... probably via a macro.
(defvar realgud:kshdb-minibuffer-history nil
  "minibuffer history list for the command `kshdb'.")

(easy-mmode-defmap kshdb-minibuffer-local-map
  '(("\C-i" . comint-dynamic-complete-filename))
  "Keymap for minibuffer prompting of gud startup command."
  :inherit minibuffer-local-map)

;; FIXME: I think this code and the keymaps and history
;; variable chould be generalized, perhaps via a macro.
(defun kshdb-query-cmdline (&optional opt-debugger)
  (realgud-query-cmdline
   'kshdb-suggest-invocation
   kshdb-minibuffer-local-map
   'realgud:kshdb-minibuffer-history
   opt-debugger))

;;; FIXME: DRY this with other *-parse-cmd-args routines
(defun kshdb-parse-cmd-args (orig-args)
  "Parse command line ARGS for the annotate level and name of script to debug.

ARGS should contain a tokenized list of the command line to run.

We return the a list containing
- the command processor (e.g. kshdb) and it's arguments if any - a list of strings
- the name of the debugger given (e.g. kshdb) and its arguments - a list of strings
- the script name and its arguments - list of strings
- whether the annotate or emacs option was given ('-A', '--annotate' or '--emacs) - a boolean

For example for the following input
  (map 'list 'symbol-name
   '(ksh -W -C /tmp kshdb --emacs ./gcd.rb a b))

we might return:
   ((ksh -W -C) (kshdb --emacs) (./gcd.rb a b) 't)

NOTE: the above should have each item listed in quotes.
"

  ;; Parse the following kind of pattern:
  ;;  [ksh ksh-options] kshdb kshdb-options script-name script-options
  (let (
	(args orig-args)
	(pair)          ;; temp return from
	;; ksh doesn't have any optional two-arg options
	(ksh-opt-two-args '())
	(ksh-two-args '("o" "c"))

	;; One dash is added automatically to the below, so
	;; h is really -h and -host is really --host.
	(kshdb-two-args '("A" "-annotate" "l" "-library"
			  "-highlight" "-no-highlight"
			   "c" "-command" "-t" "-tty"
			   "x" "-eval-command"))
	(kshdb-opt-two-args '())
	(interp-regexp
	 (if (member system-type (list 'windows-nt 'cygwin 'msdos))
	     "^ksh*\\(.exe\\)?$"
	   "^ksh*$"))

	;; Things returned
	(script-name nil)
	(debugger-name nil)
	(interpreter-args '())
	(debugger-args '())
	(script-args '())
	(annotate-p nil))

    (if (not (and args))
	;; Got nothing: return '(nil, nil)
	(list interpreter-args debugger-args script-args annotate-p)
      ;; else
      ;; Strip off optional "ruby" or "ruby182" etc.
      (when (string-match interp-regexp
			  (file-name-sans-extension
			   (file-name-nondirectory (car args))))
	(setq interpreter-args (list (pop args)))

	;; Strip off Ruby-specific options
	(while (and args
		    (string-match "^-" (car args)))
	  (setq pair (realgud-parse-command-arg
		      args ksh-two-args ksh-opt-two-args))
	  (nconc interpreter-args (car pair))
	  (setq args (cadr pair))))

      ;; Remove "kshdb" from "kshdb --kshdb-options script
      ;; --script-options"
      (setq debugger-name (file-name-sans-extension
			   (file-name-nondirectory (car args))))
      (unless (string-match "^kshdb$" debugger-name)
	(message
	 "Expecting debugger name `%s' to be `kshdb'"
	 debugger-name))
      (setq debugger-args (list (pop args)))

      ;; Skip to the first non-option argument.
      (while (and args (not script-name))
	(let ((arg (car args)))
	  (cond
	   ;; Annotation or emacs option with level number.
	   ((or (member arg '("--annotate" "-A"))
		(equal arg "--emacs"))
	    (setq annotate-p t)
	    (nconc debugger-args (list (pop args))))
	   ;; Combined annotation and level option.
	   ((string-match "^--annotate=[0-9]" arg)
	    (nconc debugger-args (list (pop args)) )
	    (setq annotate-p t))
	   ;; Options with arguments.
	   ((string-match "^-" arg)
	    (setq pair (realgud-parse-command-arg
			args kshdb-two-args kshdb-opt-two-args))
	    (nconc debugger-args (car pair))
	    (setq args (cadr pair)))
	   ;; Anything else must be the script to debug.
	   (t (setq script-name (realgud:expand-file-name-if-exists arg))
	       (setq script-args (cons script-name (cdr args))))
	   )))
      (list interpreter-args debugger-args script-args annotate-p))))

;;To silence Warning: reference to free variable
(defvar realgud:kshdb-command-name)

(defun kshdb-suggest-invocation (debugger-name)
  "Suggest a kshdb command invocation via `realgud-suggest-invocaton'"
  (realgud-suggest-invocation realgud:kshdb-command-name
			      realgud:kshdb-minibuffer-history
			      "sh" "\\.\\(?:k\\)?sh$"))

(defun kshdb-reset ()
  "Kshdb cleanup - remove debugger's internal buffers (frame,
breakpoints, etc.)."
  (interactive)
  ;; (kshdb-breakpoint-remove-all-icons)
  (dolist (buffer (buffer-list))
    (when (string-match "\\*kshdb-[a-z]+\\*" (buffer-name buffer))
      (let ((w (get-buffer-window buffer)))
        (when w
          (delete-window w)))
      (kill-buffer buffer))))

;; (defun kshdb-reset-keymaps()
;;   "This unbinds the special debugger keys of the source buffers."
;;   (interactive)
;;   (setcdr (assq 'kshdb-debugger-support-minor-mode minor-mode-map-alist)
;; 	  kshdb-debugger-support-minor-mode-map-when-deactive))


(defun realgud:kshdb-customize ()
  "Use `customize' to edit the settings of the `kshdb' debugger."
  (interactive)
  (customize-group 'realgud:kshdb))

(provide-me "realgud:kshdb-")
